JVM Programming

Author

Ken Pu

1 Flow Control

JVM provides several instructions to perform comparisons and logical predicates. These instructions are used for conditional branching and decision-making within Java bytecode.

1.1 Comparison Instructions

  1. Integer Comparison with ZERO:
    • ifeq: Branch if int is equal to zero
      • Example: ifeq Label
      • Before: [... 0]
      • After: [...] (branch taken if top of stack is 0)
    • ifne: Branch if int is not equal to zero
      • Example: ifne Label
      • Before: [... x]
      • After: [...] (branch taken if x is not 0)
    • iflt: Branch if int is less than zero
      • Example: iflt Label
      • Before: [... x]
      • After: [...] (branch taken if x < 0)
    • ifge: Branch if int is greater than or equal to zero
      • Example: ifge Label
      • Before: [... x]
      • After: [...] (branch taken if x >= 0)
    • ifgt: Branch if int is greater than zero
      • Example: ifgt Label
      • Before: [... x]
      • After: [...] (branch taken if x > 0)
    • ifle: Branch if int is less than or equal to zero
      • Example: ifle Label
      • Before: [... x]
      • After: [...] (branch taken if x <= 0)
  2. Integer Comparison with Two Operands:
    • if_icmpeq: Branch if two ints are equal
      • Example: if_icmpeq Label
      • Before: [... x, y]
      • After: [...] (branch taken if x == y)
    • if_icmpne: Branch if two ints are not equal
      • Example: if_icmpne Label
      • Before: [... x, y]
      • After: [...] (branch taken if x != y)
    • if_icmplt: Branch if one int is less than another
      • Example: if_icmplt Label
      • Before: [... x, y]
      • After: [...] (branch taken if x < y)
    • if_icmpge: Branch if one int is greater than or equal to another
      • Example: if_icmpge Label
      • Before: [... x, y]
      • After: [...] (branch taken if x >= y)
    • if_icmpgt: Branch if one int is greater than another
      • Example: if_icmpgt Label
      • Before: [... x, y]
      • After: [...] (branch taken if x > y)
    • if_icmple: Branch if one int is less than or equal to another
      • Example: if_icmple Label
      • Before: [... x, y]
      • After: [...] (branch taken if x <= y)

1.2 Logical Predicate Instructions

  1. Bitwise Logical Operations:
    • iand: Perform bitwise AND on integers
      • Example: iand
      • Before: [... x, y]
      • After: [... (x & y)]
    • ior: Perform bitwise OR on integers
      • Example: ior
      • Before: [... x, y]
      • After: [... (x | y)]
    • ixor: Perform bitwise XOR on integers
      • Example: ixor
      • Before: [... x, y]
      • After: [... (x ^ y)]

These instructions are primarily used for branching in control structures such as loops and conditional statements.

1.3 Example

Let’s compute the sum of the first 1000 integers: 0 + 1 + 2 + … + 999

Here is the pseudo-code we are implementing:

int sum = 0;         // $1
int i = 0;           // $2
while(i < 1000) {
    sum += 1;
    i += 1;
}
%%jvm stack=10 locals=10
iconst_0
istore_1           ;; sum = 0
iconst_0
istore_2           ;; i = 0

LOOP:              ;; WHILE
iload_2
ldc 1000
if_icmpeq END      ;; if i == 1000: break
iload_2
iload_1
iadd
istore_1           ;; sum = i + sum
iinc 2 1           ;; i += 1
goto LOOP          ;; END WHILE
END:
    
getstatic java/lang/System/out Ljava/io/PrintStream; 
iload_1
invokevirtual java/io/PrintStream/println(I)V
Generated: Hello.class

! java Hello
499500

2 Method declaration and invocation

%%jvm
.class public Hello
.super java/lang/Object

.method public static println(Ljava/lang/String;)V
    .limit stack 2
    .limit locals 1
    getstatic java/lang/System/out Ljava/io/PrintStream; 
    aload_0
    invokevirtual java/io/PrintStream/println(Ljava/lang/String;)V
    return
.end method

.method public static println(I)Ljava/lang/String;
    .limit stack 2
    .limit locals 11
    getstatic java/lang/System/out Ljava/io/PrintStream; 
    iload_0
    invokevirtual java/io/PrintStream/println(I)V
    ldc "completed"
    areturn
.end method

.method public static main([Ljava/lang/String;)V
    .limit stack 1
    ldc "result"                                      ;; ["result"]
    invokestatic Hello/println(Ljava/lang/String;)V   ;; []
    ldc 100                                           ;; [100]
    invokestatic Hello/println(I)Ljava/lang/String;   ;; ["completed"]
    invokestatic Hello/println(Ljava/lang/String;)V   ;; []
    return
.end method
Generated: Hello.class

! java Hello
result
100
completed